Querying Wikidata, IMDB, dblp and more with GQL

This service answers queries in GQL, the ISO standard Graph Query Language (ISO/IEC 39075). The queries run on butterfly, a graph query engine that is specialised in path queries.

The service holds four property graphs, each in its own database: Wikidata, the IMDB movie database, dblp and the Mathematics Genealogy Project, and the German rail timetable. Choose the database with the selection next to the Examples button; a query runs on the selected database only. The choice is kept in the address (?db=gtfs), so links to a query include it, and choosing an example selects its database.

Your first query

A GQL query describes a pattern of nodes and edges in MATCH and says what to output in RETURN:

MATCH (cat)-[:P31]->(:Q146)
RETURN cat, cat.label AS catLabel
LIMIT 100

This query finds every node cat with an edge labelled P31 (instance of) to the node Q146 (house cat). It returns the node and its label. Write the query in the editor and press the run button or Ctrl+Enter.

The same works for IMDB, once IMDB is selected as the database:

MATCH (actor:Person)-[role:ActedIn]->(:Movie {title: 'The Matrix'})
RETURN actor.name AS actor, role.character AS character

Datasets

Wikidata

The Wikidata subgraph is built from a Wikidata JSON dump.

Descriptions, aliases and sitelinks are not part of the graph. References are not loaded. Because an item is identified by its id label, WHERE x = 'Q42' does not work: write (x:Q42) instead.

The target of an edge is another item or a value. Values are returned as follows:

To find the id of an item or property, type its name after a colon in the editor and press Ctrl+Space, see Editor. You can also search on wikidata.org.

IMDB

The IMDB subgraph is built from the IMDB non-commercial datasets. Every node has the label Person, Title or AkaTitle. Titles have a second label for their type.

IMDB nodes are returned as their IMDB id, e.g. tt0133093. To show names and titles, return their properties: RETURN p.name AS name.

dblp and the Mathematics Genealogy Project

This database holds the computer science bibliography dblp (CC0) and the Mathematics Genealogy Project (MGP), which records who supervised whose doctorate, in one graph. About 11,000 people in dblp link to their MGP entry, so a path can lead from co-authors to academic ancestors.

Names are spelled as on mathgenealogy.org and dblp.org, e.g. 'Domagoj Vrgoc'; people in dblp with the same name carry a number, e.g. 'Wei Wang 0001'. On a graph of this size, leave labels out of a Kleene star and filter the publications: a co-author chain through ISWC papers, ( ()-[:Authored]->(p WHERE p.venueKey = 'conf/semweb')<-[:Authored]-() )*, takes about a second, one through all of dblp about two minutes.

German rail timetable (GTFS)

The timetable of all trains in Germany (long-distance, regional and S-Bahn) on one day, Tuesday 27 October 2026, from the gtfs.de feed of DELFI e.V. (Creative Commons 4.0). It is a time-expanded graph: every departure and arrival of a train at a stop is a node, so every path through it is possible in time, and the waiting time of each change of trains is a property of its edge.

A trip is the pattern Board Ride (Stay Ride)* (Transfer Ride (Stay Ride)*)* Alight, with one Kleene star for the legs of the trip and one inside it for the stops of a leg. A change leads to the first departure of each line and direction that can be reached, after at least 4 minutes. SHORTEST finds the trip with the fewest stops and changes, not the one that arrives first: ANY SHORTEST returns one of several equally short trips, which may differ from run to run, and ALL SHORTEST lists them all.

GQL syntax

butterfly implements the read-only part of GQL that is about pattern matching, with a focus on paths. This section describes what is supported. See Limitations for what is not.

Query structure

A query is a sequence of statements, ending with RETURN:

MATCH <pattern>, <pattern> [WHERE <condition>]
[OPTIONAL MATCH <pattern> …]
[MATCH …]
RETURN <expression> [AS <name>], …
[ORDER BY <expression> [ASC | DESC], …]
[SKIP <n>] [LIMIT <n>]

Patterns that share a variable are joined, whether they are separated by commas or in different MATCH statements. Comments are written as // … or /* … */.

Node patterns

Edge patterns

Nodes and edges alternate. A chain can be as long as needed:

// Directors Keanu Reeves worked with
MATCH (:Person {name: 'Keanu Reeves'})-[:ActedIn]->(movie:Movie)<-[:Directed]-(director:Person)
RETURN director.name AS director, movie.title AS movie

Properties

x.name reads the property name of the node or edge x. For Wikidata, use the property id, e.g. e.P580 for the start time qualifier of the edge e.

WHERE

Conditions can be written after MATCH, inside a node or edge pattern, or inside a path pattern.

// Nobel laureates in physics who also received the Nobel Prize in Chemistry
MATCH (p)-[:P166]->(:Q38104)
WHERE EXISTS { (p)-[:P166]->(:Q44585) }
RETURN p, p.label AS pLabel

OPTIONAL MATCH

OPTIONAL MATCH keeps the rows of the preceding patterns even if the optional pattern has no match. Its variables are then empty.

MATCH (country)-[:P31]->(:Q3624078)
OPTIONAL MATCH (country)-[:P36]->(capital)
RETURN country, country.label AS countryLabel, capital

Paths

Path queries are what butterfly is built for. A quantifier after an edge or after a parenthesised sub-pattern repeats it:

// All subclasses of musical instrument (Q34379), like wdt:P279+ in SPARQL
MATCH (instrument)-[:P279]->+(:Q34379)
RETURN instrument, instrument.label AS instrumentLabel

// instance of a subclass of mountain, like wdt:P31/wdt:P279* in SPARQL
MATCH (mountain)-[:P31]->( ()-[:P279]-> )* (:Q8502)
RETURN mountain

A quantified sub-pattern can contain nodes with conditions and alternatives (|), and quantifiers can be nested. A variable inside a quantified sub-pattern is bound to the list of all its matches along the path:

// s is the list of stations on the route
MATCH ANY SHORTEST (:Q801394) ( () -[:P197]-> (s) )* (:Q742238)
RETURN [x IN s | x.label] AS stations

A prefix in front of the pattern selects which paths are returned:

RETURN

RETURN lists the columns of the result. Give a column a name with AS; without it, n.label becomes a column named n__label. RETURN * returns all variables.

ORDER BY refers to the returned columns. It sorts nodes and properties by their internal id, which is not alphabetical. To sort numbers by value, sort by an arithmetic expression such as ORDER BY rating * 1 DESC.

A list comprehension turns a list variable into a list of values:

RETURN [m IN movie WHERE m.rating > 7 | m.title] AS goodMovies

Result views

Choose how the result is displayed with the menu above the result. A comment in the query selects the view that is used when the query is run:

// #defaultView:Map
MATCH (lighthouse)-[:P31]->(:Q39715), (lighthouse)-[:P17]->(:Q20), (lighthouse)-[:P625]->(coordinates)
RETURN lighthouse, lighthouse.label AS lighthouseLabel, coordinates

For a Wikidata item in column x, a text column named xLabel is used as its label in the table, the graph and the map. Options can follow the view name, e.g. // #defaultView:ImageGrid{"hide": ["image"]} hides the column image.

Editor

• Ctrl+Enter runs the query. Ctrl+Space completes the word at the cursor.
• After a colon, completion searches Wikidata and inserts the id: (:human becomes (:Q5, and -[:instance of becomes -[:P31. It also completes the IMDB labels.
• Hover over a Wikidata id like Q42 to see its label and description.
• Errors in the query are highlighted in the editor and explained below it.
• The Link menu gives a link to the query or to the result, and the Code button shows how to run the query with curl or Python. The service answers HTTP GET and POST requests with the parameter query, in the SPARQL JSON result format.

Limitations

• Keywords must be upper case.
• No functions and no aggregation: count(), sum(), DISTINCT, GROUP BY, string functions and the like are not supported.
• No UNWIND, CALL, parameters, list literals or path variables (p = (…)), and no changes to the data.
• ORDER BY sorts nodes and properties by internal id; sort by an arithmetic expression to sort numbers by value.
• Reading a property drops rows without that property.
• = compares node identity; comparisons with < and > and arithmetic only work on numbers. Wikidata quantities and times cannot be compared.
• Wikidata only contains statements of the best rank, one label per item, and no descriptions, aliases or references.
• SHORTEST means the fewest edges, not a shortest distance or time; among equally short paths, ANY SHORTEST may return a different one on each run.

Examples

The query editor has example queries for all four databases. Open them with the Examples button; choosing an example also selects its database.

• Wikidata: Query 1 of the PathExtractor paper, the stations from Saint-Michel–Notre-Dame to Aéroport Charles de Gaulle 1, with the Station label and as a nested regular expression.
• IMDB: Query 2 of the paper, the actors connected to Kevin Bacon only through B-movies, and the same chain from Sean Bean.
• dblp and Math Genealogy: doctoral lineages, how two authors of the paper are related academically, and co-author chains through ISWC papers.
• German rail timetable: journeys from Bayreuth to München: with changes, with the Deutschlandticket, with time to spare at every change, and all equally short connections.